#declare SLOT = box { <-0.2,2,5> <0.2,1.05,0> }
#declare SLOTS =
 union {
  object { SLOT }
  object { SLOT rotate <0,24,0> }
  object { SLOT rotate <0,48,0> }
  object { SLOT rotate <0,72,0> }
  object { SLOT rotate <0,96,0> }
 }
#declare CYLINDER =
 union {
  difference {
   difference {
    cylinder { <0,1.3,0>,<0,0,0>, 4.2 open }
    cylinder { <0,1.3,0>,<0,0,0>, 4.1 open }
   }
   object { SLOTS }
   object { SLOTS rotate <0,120,0> }
   object { SLOTS rotate <0,240,0> }
   pigment { rgb 0.5 }
  }
  cylinder { <0,1,0>,<0,0,0>, 4 open
   texture {
    pigment { image_map {
     png "Muybridge_race_horse_animated.png"
     map_type 2
     once interpolate 2
    } }
   }
   finish { ambient rgb 0.6 }
   rotate <0,6,0>
  }
  rotate <0,clock*360/60,0>
  scale  <-1,1,1>
 }

object { CYLINDER translate <0, 0,0> }
object { CYLINDER translate <0,-3.55,-0.75> rotate <-24,0,0> }
background   { color rgbt <1,1,1,0> }
light_source { <0,1,7> color 1 parallel
 // area_light <2,2,0>, <-2,-2,0>, 3, 3 adaptive 1 jitter
}
camera {
 right    x * image_width / image_height
 location <0,1.43,7>
 look_at  <0,-2.15,0>
 angle    68
}